Usando Acelerômetro no Flash Lite 4.0

Colocado por Leonardo França na(s) categoria(s): 1, 4, 6, action, Actionscript, ActionScript 3, Actionscript 3.0, Actionscript3, Adobe, api, Aplicativos, AR, back, bar, BI, bitmap, browser, cache, camp, class, classe, classes, código, Curso, Cursos, custom, dados, Desenvolvimento, Download, Draw, efeito, efeitos, engine, err, event, EventListener, exemplo, filter, flash, flash lite, Flash Player, Flex, for, function, geo, Google, handle, html, IE, if, image, int, Java, Javascript, lite, live, map, mg, Number, O, on, PHP, player, pt, rest, RIA, Ria’s Geral, RTM, RTMP, streaming, string, tag, Tema, Touch, UI, update, Ved, Widget, Widgets em 10 15th, 2010 | Sem comentários

Tivemos o lançamento do Nokia N8, o primeiro dispositivo oficialmente a suportar Flash Lite 4.0. Além do Nokia N8 [bb] , também temos o Nokia C7 [bb] e o Nokia E7 [bb] , todos rodando o sistema operacional Symbian^3 e com o Adobe Flash Lite 4.0 já instalado. Isso implica a possibilidade do desenvolvimento de aplicativos para Symbian^3 usando ActionScript 3.0 rodando pelo browser ou standalone.
Precisamos atentar para o fato de que o Flash Lite 4.0 não é o Flash Player 10.1, eles possuem algumas diferenças significativas:

Flash Lite suporta algumas funcionalidades parcialmente.
Flash Lite adiciona algumas funcionalidades para trabalhar especificamente com dispositivos movéis.

O Flash Lite 4.0 é baseado no Flash Player 10, possuindo recursos que foram introduzido no Flash Player 9 e 10. Entre os recursos disponivéis estão:

Multi-touch support
Flash Player 10 text engine
Using inline text input
RTMP data channel
RTMPE
RTMPT and RTMPTE
Multi bit-rate streaming
Geolocation
Accelerometer
SharedObject Remote(Obaaaa! )

Além disso veja as classes parcialmente suportadas e as classes não suportadas.
Vamos ao nosso primeiro exemplo com utilização das novas capacidades do Flash Lite 4.0, nesse caso, acelerômetro.

Crie um arquivo do tipo Flash Lite 4.0 pelo Flash CS5 ou pelo Adobe Device Central CS5.
Adicione três campos de textos dinâmicos, neles serão mostrados as coordenadas de x, y e z.

Começaremos nossa codificação, teremos um método para criar a bola que sofrerá os efeitos do acelerômetro

PLAIN TEXT

ACTIONSCRIPT3:

function createBall():void
{
    ball = new Sprite();
    ball.graphics.beginFill(0xFF0000);
    ball.graphics.drawCircle(0, 0, RADIUS);
    ball.cacheAsBitmap = true;
    ball.x = stage.stageWidth / 2;
    ball.y = stage.stageHeight / 2;
    addChild(ball);
}

Em seguida, verificamos se o aparelho tem acelerômetro para adicionarmos os listeners que pega os dados do sensor e para atualizar as posições da bola.

PLAIN TEXT

ACTIONSCRIPT3:

function AccelerometerTest()
{
    stage.scaleMode = StageScaleMode.NO_SCALE;
    stage.align = StageAlign.TOP_LEFT;
 
    createBall();
 
    if (Accelerometer.isSupported)
    {
        accelerometer = new Accelerometer();
        accelerometer.addEventListener(AccelerometerEvent.UPDATE, accUpdateHandler);
        stage.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
    }
}

E o restante do código.

PLAIN TEXT

ACTIONSCRIPT3:

function enterFrameHandler(event:Event):void
{
    event.stopPropagation();
    moveBall();
}
function moveBall():void
{
    var newX:Number = ball.x + xSpeed;
    var newY:Number = ball.y + ySpeed;
    if (newX <20)
    {
        ball.x = RADIUS;
        xSpeed = 0;
    }
    else if (newX> stage.stageWidth - RADIUS)
    {
        ball.x = stage.stageWidth - RADIUS;
        xSpeed = 0;
    }
    else
    {
        ball.x +=  xSpeed;
    }
 
    if (newY <RADIUS)
    {
        ball.y = RADIUS;
        ySpeed = 0;
    }
    else if (newY> stage.stageHeight - RADIUS)
    {
        ball.y = stage.stageHeight - RADIUS;
        ySpeed = 0;
    }
    else
    {
        ball.y +=  ySpeed;
    }
}
 
function accUpdateHandler(event:AccelerometerEvent):void
{
    xSpeed +=  event.accelerationX * 2;
    ySpeed -=  event.accelerationY * 2;
    
    txtX.text = new String(event.accelerationX);
    txtY.text = new String(event.accelerationY);
    txtZ.text = new String(event.accelerationZ);
}